Commit 80af61d7 authored by Pavan Balaji's avatar Pavan Balaji
Browse files

[svn-r4134] Added an svn:externals link to get the mpich2 confdb to the local

directory. This will reduce on dependency of Hydra on the MPICH2
directory structure. A million more to go.
parent 2bc091d0
#
# Not yet a conforming Makefile...
#
SHELL = @SHELL@
SOURCES = aclocal.m4 aclocal_cache.m4 aclocal_cc.m4 aclocal_cross.m4 \
aclocal_f77.m4 aclocal_f90.m4 aclocal_make.m4 \
aclocal_mpi.m4 aclocal_perl.m4 \
aclocal_shl.m4 aclocal_cxx.m4 aclocal_bugfix.m4 \
aclocal_am.m4 aclocal_web.m4 aclocal_java.m4
config_SOURCES = acconfig.h.in acconfig_cc.h acconfig_f77.h
DOCTEXT = ../src/doctext/doctext
DOCTEXT_ARGS = -nolocation -heading Sowing -quotefmt -skipprefix dnl
all: htmldoc texdoc
.SUFFIXES: .tex .html .m4
htmldoc: ${SOURCES}
${DOCTEXT} ${DOCTEXT_ARGS} -html -mpath www ${SOURCES}
rm -f www/index.htm
@echo '<HTML><TITLE>PAC Documentation</TITLE>' >www/index.htm
@echo '<BODY BGCOLOR="FFFFFF">' >>www/index.htm
@echo '<MENU>' >>www/index.htm
@(cd www && ls -1 *.html | sed 's%^\(.*\)\.html%<LI> <A HREF="\1.html">\1</A>%g' >>\
index.htm )
@echo '</MENU></BODY></HTML>' >>www/index.htm
texdoc: ${SOURCES}
${DOCTEXT} ${DOCTEXT_ARGS} -latex -mpath tex ${SOURCES}
rm -f tex/ref.tex
@(cd tex && ls -1 *.tex | sed 's%^\(.*\)\.tex%\\input \1.tex%g' > ../ref.tex)
@mv ref.tex tex/ref.tex
@(cd tex && @LATEX@ ../pac && dvips pac && dvipdfm pac)
@mv tex/pac.pdf .
@mv tex/pac.ps .
acconfig.h: ${config_SOURCES}
@-rm -f acconfig.h
cat ${config_SOURCES} | sed '/#include/d' > acconfig.h
clean:
-rm -f *~ tex/*.log tex/*.aux tex/*.dvi
dist-clean: clean
rm -f config.cache config.log config.status Makefile
maintainer-clean: dist-clean
This directory contains autoconf version 2 (2.13) aclocal.m4 files
They are organized by category, so that you can include subsets in your own
aclocal.m4 files if you prefer (the aclocal.m4 file here includes them
all).
/* This is a parallel file to aclocal.m4. It uses includes the same
way that aclocal.m4 does. Unfortunately, autoheader doesn't process
the acconfig.h files with cpp or with m4. Thus, we use acconfig.h.in
to form acconfig.h with cpp
*/
#include "acconfig_f77.h"
#include "acconfig_cc.h"
#include "acconfig_mpi.h"
/* acconfig_cc.h */
/* Define if union semun is defined in sys/sem.h */
#undef HAVE_UNION_SEMUN
/* Define if semctl requires a union semun argument in the 4th position */
#undef SEMCTL_NEEDS_SEMUN
/* Define as empty if C does not support volatile */
#undef volatile
/* Define if #pragma weak supported */
#undef HAVE_PRAGMA_WEAK
/* Define is #pragma _HP_SECONDARY_DEF supported */
#undef HAVE_PRAGMA_HP_SEC_DEF
/* Define is #pragma _CRI duplicate x as y supported */
#undef HAVE_PRAGMA_CRI_DUP
/* Define if crypt requires a prototype */
#undef NEED_CRYPT_PROTOTYPE
/* Define as empty if C does not support any form of restrict or define
as the appropriate extension */
#undef restrict
/* Define if the XOPEN versions of routines and header files are needed */
#undef _XOPEN_SOURCE
/* Define as empty if C does not support inline */
#undef inline
/* acconfig_f77.h */
/* Define if Fortran uses lowercase name mangling */
#undef F77_NAME_LOWER
/* Define if Fortran use lowercase followed by an underscore */
#undef F77_NAME_LOWER_USCORE
/* Define if Fortran uses uppercase */
#undef F77_NAME_UPPER
/* Define if Fortran uses two underscores for names with an underscore
(and one for names without an underscore) */
#undef F77_NAME_LOWER_2USCORE
/* Define if Fortran leaves case unchanged */
#undef F77_NAME_MIXED
/* Define if Fortran leaves case unchanged, followed by an underscore */
#undef F77_NAME_MIXED_USCORE
/* Sizeof standard Fortran types */
#undef SIZEOF_F77_DOUBLE_PRECISION
#undef SIZEOF_F77_INTEGER
#undef SIZEOF_F77_INTEGER_4
#undef SIZEOF_F77_REAL
/* Define if MPI_xxx_f2c and c2f routines defined */
#undef HAVE_MPI_F2C
This diff is collapsed.
dnl
dnl This version of aclocal.m4 simply includes all of the individual
dnl components
builtin(include,aclocal_am.m4)
builtin(include,aclocal_bugfix.m4)
builtin(include,aclocal_cache.m4)
builtin(include,aclocal_cc.m4)
builtin(include,aclocal_atomic.m4)
builtin(include,aclocal_cross.m4)
builtin(include,aclocal_cxx.m4)
builtin(include,aclocal_f77.m4)
builtin(include,aclocal_util.m4)
builtin(include,aclocal_subcfg.m4)
dnl If we're using 2.52, include new support for F90
dnl If we're using 2.13, use the old version
dnl If we're using 2.57, we're in trouble.
dnl !!!! 2.57 doesn't define AC_ACVERSION !!!!
dnl 2.57 seems to define AC_PREPROC_IFELSE, so we use that
dnl
ifelse(AC_ACVERSION,[2.52],[
builtin(include,aclangf90.m4)
],[
ifdef([AC_PREPROC_IFELSE],[
builtin(include,fortran90.m4)],
[builtin(include,aclocal_f90.m4)])
])
dnl builtin(include,aclocal_csharp.m4)
builtin(include,aclocal_make.m4)
builtin(include,aclocal_mpi.m4)
builtin(include,aclocal_web.m4)
builtin(include,libtool.m4)
builtin(include,aclocal_shl.m4)
dnl builtin(include,aclocal_tcl.m4)
builtin(include,aclocal_java.m4)
dnl
dnl Newer versions of autoconf support AC_EXEEXT and AC_OBJEXT.
dnl If these are not available, just set them as empty
ifdef([AC_EXEEXT],,[
AC_DEFUN(AC_EXEEXT,[
EXEEXT=
AC_SUBST(EXEEXT)
])])
ifdef([AC_OBJEXT],,[
AC_DEFUN(AC_OBJEXT,[
OBJEXT=
AC_SUBST(OBJEXT)
])])
dnl
dnl PAC_MKDIRS(path)
dnl Create any missing directories in the path
dnl
AC_DEFUN([PAC_MKDIRS],[
#
# Build any intermediate directories
for dir in $1 ; do
saveIFS="$IFS"
IFS="/"
tmp_curdir=""
for tmp_subdir in $dir ; do
tmp_curdir="${tmp_curdir}$tmp_subdir"
if test ! -d "$tmp_curdir" ; then mkdir "$tmp_curdir" ; fi
tmp_curdir="${tmp_curdir}/"
done
IFS="$saveIFS"
done
])
dnl
dnl PAC_CONFIG_SUBDIRS_IMMEDIATE(DIR ...)
dnl Perform the configuration *now*
dnl
dnl There is a bug in AC_OUTPUT_SUBDIRS that is tickled by this
dnl code. There is no step to create any of the intermediate
dnl directories in the case that this is a vpath build.
dnl
AC_DEFUN(PAC_CONFIG_SUBDIRS_IMMEDIATE,
[AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
SAVE_subdirs="$subdirs"
subdirs="$1"
#
# Build any intermediate directories
for dir in $1 ; do
saveIFS="$IFS"
IFS="/"
curdir=""
for subdir in $dir ; do
curdir="${curdir}$subdir"
if test ! -d "$curdir" ; then mkdir "$curdir" ; fi
curdir="${curdir}/"
done
IFS="$saveIFS"
done
PAC_CACHE_CLEAN
dnl autoconf 2.52 uses _ before *some* internal commands (!)
dnl output_subdirs *ALSO* resets INSTALL. It *also* requires that
dnl ac_given_INSTALL be set to INSTALL
SAVE_INSTALL="$INSTALL"
ac_given_INSTALL="$INSTALL"
ifdef([AC_OUTPUT_SUBDIRS],[AC_OUTPUT_SUBDIRS($1)],[_AC_OUTPUT_SUBDIRS($1)])
subdirs="$SAVE_subdirs"
INSTALL="$SAVE_INSTALL"
])
dnl
dnl Find something to use for mkdir -p. Eventually, this will
dnl have a script for backup
AC_DEFUN(PAC_PROG_MKDIR_P,[
AC_CACHE_CHECK([whether mkdir -p works],
pac_cv_mkdir_p,[
pac_cv_mkdir_p=no
rm -rf .tmp
if mkdir -p .tmp/.foo 1>/dev/null 2>&1 ; then
if test -d .tmp/.foo ; then
pac_cv_mkdir_p=yes
fi
fi
rm -rf .tmp
])
if test "$pac_cv_mkdir_p" = "yes" ; then
MKDIR_P="mkdir -p"
export MKDIR_P
else
AC_MSG_WARN([mkdir -p does not work; the install step may fail])
fi
AC_SUBST(MKDIR_P)
])
dnl
dnl Test for a clean VPATH directory. Provide this command with the names
dnl of all of the generated files that might cause problems
dnl (Makefiles won't cause problems because there's no VPATH usage for them)
dnl
dnl Synopsis
dnl PAC_VPATH_CHECK([file-names],[directory-names])
dnl file-names should be files other than config.status and any header (e.g.,
dnl fooconf.h) file that should be removed. It is optional
AC_DEFUN([PAC_VPATH_CHECK],[
rm -f conftest*
date >conftest$$
# If creating a file in the current directory does not show up in the srcdir
# then we're doing a VPATH build (or something is very wrong)
if test ! -s $srcdir/conftest$$ ; then
pac_dirtyfiles=""
pac_dirtydirs=""
pac_header=""
ifdef([AC_LIST_HEADER],[pac_header=AC_LIST_HEADER])
for file in config.status $pac_header $1 ; do
if test -f $srcdir/$file ; then
pac_dirtyfiles="$pac_dirtyfiles $file"
fi
done
ifelse($2,,,[
for dir in $2 ; do
if test -d $srcdir/$dir ; then
pac_dirtydirs="$pac_dirtydirs $dir"
fi
done
])
if test -n "$pac_dirtyfiles" -o -n "$pac_dirtydirs" ; then
# Create a nice message about what to remove
rmmsg=""
if test -n "$pac_dirtyfiles" ; then
rmmsg="files $pac_dirtyfiles"
fi
if test -n "$pac_dirtydirs" ; then
if test -n "$rmmsg" ; then
rmmsg="$rmmsg and directories $pac_dirtydirs"
else
rmmsg="directories $pac_dirtydirs"
fi
fi
if test -f $srcdir/Makefile ; then
AC_MSG_ERROR([You cannot do a VPATH build if the source directory has been
configured. Run "make distclean" in $srcdir first and make sure that the
$rmmsg have been removed.])
else
AC_MSG_ERROR([You cannot do a VPATH build if the source directory has been
configured. Remove the $rmmsg in $srcdir.])
fi
fi
fi
rm -f conftest*
])
dnl
dnl Automake updates
dnl
dnl
dnl AM_IGNORE is an extension that tells (a patched) automake not to
dnl include the specified AC_SUBST variable in the Makefile.in that
dnl automake generates. We don't use AC_DEFUN, since aclocal will
dnl then complain that AM_IGNORE is a duplicate (if you are using the
dnl patched automake/aclocal).
ifdef([AM_IGNORE],,[
define([AM_IGNORE],)])
dnl
dnl You can use PAC_PROVIDE_IGNORE to ensure that AM_IGNORE is defined
dnl for configures that don't use automake
AC_DEFUN([PAC_PROVIDE_IGNORE],[
ifdef([AM_IGNORE],,[
define([AM_IGNORE],)])
])
dnl /*D PAC_C_MEMATOMIC - Try and determine how to implement memory-atomic
dnl operations with the selected C compiler
dnl
dnl Synopsis:
dnl PAC_C_MEMATOMIC
dnl
dnl Notes:
dnl Defines names of the following form
dnl + HAVE_GCC_ASM_AND_X86_{MFENCE,LFENCE,SFENCE} - gcc __asm__ will issue
dnl mfence, lfence, or sfence
dnl . HAVE___ASM_AND_X86_{MFENCE,LFENCE,SFENCE} - __asm _emit will issue
dnl mfence, lfence, or sfence
dnl . HAVE_ASM_AND_X86_{MFENCE,LFENCE,SFENCE} - asm("...") will issue
dnl mfence, lfence, or sfence
dnl . HAVE__INTERLOCKEDEXCHANGE - _InterlockedExchange intrinsic is available
dnl (IA64)
dnl . HAVE_GCC_ASM_SPARC_MEMBAR - gcc __asm__ will issue SPARC architecture
dnl memory barrier instruction
dnl . HAVE_SOLARIS_ASM_SPARC_MEMBAR - Solaris asm() will issue SPARC
dnl architecture memory barrier instruction
dnl . HAVE_GCC_ASM_SPARC_STBAR - gcc __asm__ will issue stbar
dnl - HAVE_SOLARIS_ASM_SPARC_STBAR - Solaris __asm() will issue stbar
dnl
dnl D*/
AC_DEFUN([PAC_C_MEMATOMIC],[
AC_CACHE_CHECK([for x86 mfence instruction using __asm__],
pac_cv_have_gcc_asm_and_x86_mfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
__asm__ __volatile__ ( ".byte 0x0f, 0xae, 0xf0" ::: "memory" );
exit(0);
}
],
pac_cv_have_gcc_asm_and_x86_mfence=yes,pac_cv_have_gcc_asm_and_x86_mfence=no)])
if test "$pac_cv_have_gcc_asm_and_x86_mfence" = "yes" ; then
AC_DEFINE(HAVE_GCC_ASM_AND_X86_MFENCE, 1, [Define if using gcc on a x86 system with the mfence instruction])
fi
AC_CACHE_CHECK([for x86 sfence instruction using __asm__],
pac_cv_have_gcc_asm_and_x86_sfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
__asm__ __volatile__ ( ".byte 0x0f, 0xae, 0xf8" ::: "memory" );
exit(0);
}
],
pac_cv_have_gcc_asm_and_x86_sfence=yes,pac_cv_have_gcc_asm_and_x86_sfence=no)])
if test "$pac_cv_have_gcc_asm_and_x86_sfence" = "yes" ; then
AC_DEFINE(HAVE_GCC_ASM_AND_X86_SFENCE, 1, [Define if using gcc on a x86 system with the sfence instruction])
fi
AC_CACHE_CHECK([for x86 lfence instruction using __asm__],
pac_cv_have_gcc_asm_and_x86_lfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
__asm__ __volatile__ ( ".byte 0x0f, 0xae, 0xe8" ::: "memory" );
exit(0);
}
],
pac_cv_have_gcc_asm_and_x86_lfence=yes,pac_cv_have_gcc_asm_and_x86_lfence=no)])
if test "$pac_cv_have_gcc_asm_and_x86_lfence" = "yes" ; then
AC_DEFINE(HAVE_GCC_ASM_AND_X86_LFENCE, 1, [Define if using gcc on a x86 system with the lfence instruction])
fi
dnl Some compilers, like icc, may want __asm _emit
AC_CACHE_CHECK([for x86 mfence instruction using __asm],
pac_cv_have___asm_and_x86_mfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
__asm _emit 0x0f __asm _emit 0xae __asm _emit 0xf0 ;
exit(0);
}
],
pac_cv_have___asm_and_x86_mfence=yes,pac_cv_have___asm_and_x86_mfence=no)])
if test "$pac_cv_have___asm_and_x86_mfence" = "yes" ; then
AC_DEFINE(HAVE___ASM_AND_X86_MFENCE, 1, [Define if using __asm on a x86 system with the mfence instruction])
fi
AC_CACHE_CHECK([for x86 sfence instruction using __asm],
pac_cv_have___asm_and_x86_sfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
__asm sfence ;
exit(0);
}
],
pac_cv_have___asm_and_x86_sfence=yes,pac_cv_have___asm_and_x86_sfence=no)])
if test "$pac_cv_have___asm_and_x86_sfence" = "yes" ; then
AC_DEFINE(HAVE___ASM_AND_X86_SFENCE, 1, [Define if using __asm on a x86 system with the sfence instruction])
fi
AC_CACHE_CHECK([for x86 lfence instruction using __asm],
pac_cv_have___asm_and_x86_lfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
__asm _emit 0x0f __asm _emit 0xae __asm _emit 0xe8 ;
exit(0);
}
],
pac_cv_have___asm_and_x86_lfence=yes,pac_cv_have___asm_and_x86_lfence=no)])
if test "$lac_cv_have___asm_and_x86_lfence" = "yes" ; then
AC_DEFINE(HAVE___ASM_AND_X86_LFENCE, 1, [Define if using __asm on a x86 system with the lfence instruction])
fi
dnl
dnl Some compilers, such as pgcc, may require additional arguments.
dnl pgcc may need -Masmkeyword flag. We may want to try this with and
dnl without adding -Masmkeyword to CFLAGS
AC_CACHE_CHECK([for x86 mfence instruction using asm()],
pac_cv_have_asm_and_x86_mfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
asm("_emit 0x0f __asm _emit 0xae __asm _emit 0xf0");
exit(0);
}
],
pac_cv_have_asm_and_x86_mfence=yes,pac_cv_have_asm_and_x86_mfence=no)])
if test "$pac_cv_have_asm_and_x86_mfence" = "yes" ; then
AC_DEFINE(HAVE_ASM_AND_X86_MFENCE, 1, [Define if using asm() on a x86 system with the mfence instruction])
fi
AC_CACHE_CHECK([for x86 sfence instruction using asm()],
pac_cv_have_asm_and_x86_sfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
asm("sfence");
exit(0);
}
],
pac_cv_have_asm_and_x86_sfence=yes,pac_cv_have_asm_and_x86_sfence=no)])
if test "$pac_cv_have_asm_and_x86_sfence" = "yes" ; then
AC_DEFINE(HAVE_ASM_AND_X86_SFENCE, 1, [Define if using asm() on a x86 system with the sfence instruction])
fi
AC_CACHE_CHECK([for x86 lfence instruction using asm()],
pac_cv_have_asm_and_x86_lfence,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
asm("_emit 0x0f __asm _emit 0xae __asm _emit 0xe8");
exit(0);
}
],
pac_cv_have_asm_and_x86_lfence=yes,pac_cv_have_asm_and_x86_lfence=no)])
if test "$pac_cv_have_asm_and_x86_lfence" = "yes" ; then
AC_DEFINE(HAVE_ASM_AND_X86_LFENCE, 1, [Define if using asm() on a x86 system with the lfence instruction])
fi
AC_CACHE_CHECK([for _InterlockedExchange intrinsic],
pac_cv_have__InterlockedExchange,[
AC_TRY_RUN([
int main(int argc, char **argv)
{
unsigned long lock, *lock_ptr;
lock_ptr = &lock;
_InterlockedExchange(lock_ptr, 1);
exit(0);
}
],
pac_cv_have__InterlockedExchange=yes,pac_cv_have__InterlockedExchange=no)])
if test "$pac_cv_have__InterlockedExchange" = "yes" ; then
AC_DEFINE(HAVE__INTERLOCKEDEXCHANGE, 1, [Define if _InterlockedExchange intrinsic is available])
fi
AC_CACHE_CHECK([for SPARC membar instruction with gcc],
pac_cv_gcc_sparc_membar,[
AC_TRY_RUN([
int main(int argc, char **argv){
__asm__ __volatile__ ( "membar #StoreLoad | #StoreStore" : : : "memory" );
exit(0);
}],pac_cv_gcc_sparc_membar=yes,pac_cv_gcc_sparc_membar=no)])
if test "$pac_cv_gcc_sparc_membar" = yes ; then
AC_DEFINE(HAVE_GCC_ASM_SPARC_MEMBAR,1,[Define if gcc asm membar supported])
fi
AC_CACHE_CHECK([for SPARC membar instruction with Solaris C],
pac_cv_solaris_sparc_membar,[
AC_TRY_RUN([
int main(int argc, char **argv){
__asm ( "membar #StoreLoad | #StoreStore");
exit(0);
}],pac_cv_solaris_sparc_membar=yes,pac_cv_solaris_sparc_membar=no)])
if test "$pac_cv_solaris_sparc_membar" = yes ; then
AC_DEFINE(HAVE_SOLARIS_ASM_SPARC_MEMBAR,1,[Define if solaris asm membar supported])
fi
AC_CACHE_CHECK([for SPARC stbar instruction with gcc],
pac_cv_gcc_sparc_stbar,[
AC_TRY_RUN([
int main(int argc, char **argv){
__asm__ __volatile__ ( "stbar" : : : "memory" );
exit(0);
}],pac_cv_gcc_sparc_stbar=yes,pac_cv_gcc_sparc_stbar=no)])
if test "$pac_cv_gcc_sparc_stbar" = yes ; then
AC_DEFINE(HAVE_GCC_ASM_SPARC_STBAR,1,[Define if gcc asm stbar supported])
fi
AC_CACHE_CHECK([for SPARC stbar instruction with Solaris C],
pac_cv_solaris_sparc_stbar,[
AC_TRY_RUN([
int main(int argc, char **argv){
__asm ( "stbar" );
exit(0);
}],pac_cv_solaris_sparc_stbar=yes,pac_cv_solaris_sparc_stbar=no)])
if test "$pac_cv_solaris_sparc_stbar" = yes ; then
AC_DEFINE(HAVE_SOLARIS_ASM_SPARC_STBAR,1,[Define if solaris asm stbar supported])
fi
])
\ No newline at end of file
dnl
dnl Fixes to bugs in AC_xxx macros
dnl
dnl (AC_TRY_COMPILE is missing a newline after the end in the Fortran
dnl branch; that has been fixed in-place)
dnl
dnl (AC_PROG_CC makes many dubious assumptions. One is that -O is safe
dnl with -g, even with gcc. This isn't true; gcc will eliminate dead code
dnl when -O is used, even if you added code explicitly for debugging
dnl purposes. -O shouldn't do dead code elimination when -g is selected,
dnl unless a specific option is selected. Unfortunately, there is no
dnl documented option to turn off dead code elimination.
dnl
dnl
dnl (AC_CHECK_HEADER and AC_CHECK_HEADERS both make the erroneous assumption
dnl that the C-preprocessor and the C (or C++) compilers are the same program
dnl and have the same search paths. In addition, CHECK_HEADER looks for
dnl error messages to decide that the file is not available; unfortunately,
dnl it also interprets messages such as "evaluation copy" and warning messages
dnl from broken CPP programs (such as IBM's xlc -E, which often warns about
dnl "lm not a valid option"). Instead, we try a compilation step with the
dnl C compiler.
dnl
dnl AC_CONFIG_AUX_DIRS only checks for install-sh, but assumes other
dnl values are present. Also doesn't provide a way to override the
dnl sources of the various configure scripts. This replacement
dnl version of AC_CONFIG_AUX_DIRS overcomes this.
dnl Internal subroutine.
dnl Search for the configuration auxiliary files in directory list $1.
dnl We look only for install-sh, so users of AC_PROG_INSTALL
dnl do not automatically need to distribute the other auxiliary files.
dnl AC_CONFIG_AUX_DIRS(DIR ...)
dnl Also note that since AC_CONFIG_AUX_DIR_DEFAULT calls this, there
dnl isn't a easy way to fix it other than replacing it completely.
dnl This fix applies to 2.13
dnl/*D
dnl AC_CONFIG_AUX_DIRS - Find the directory containing auxillery scripts
dnl for configure
dnl
dnl Synopsis:
dnl AC_CONFIG_AUX_DIRS( [ directories to search ] )
dnl
dnl Output Effect:
dnl Sets 'ac_config_guess' to location of 'config.guess', 'ac_config_sub'
dnl to location of 'config.sub', 'ac_install_sh' to the location of
dnl 'install-sh' or 'install.sh', and 'ac_configure' to the location of a
dnl Cygnus-style 'configure'. Only 'install-sh' is guaranteed to exist,
dnl since the other scripts are needed only by some special macros.
dnl
dnl The environment variable 'CONFIG_AUX_DIR', if set, overrides the
dnl directories listed. This is an extension to the 'autoconf' version of
dnl this macro.
dnl D*/
undefine([AC_CONFIG_AUX_DIRS])
AC_DEFUN(AC_CONFIG_AUX_DIRS,
[if test -f $CONFIG_AUX_DIR/install-sh ; then ac_aux_dir=$CONFIG_AUX_DIR
else
ac_aux_dir=
# We force the test to use the absolute path to ensure that the install
# program can be used if we cd to a different directory before using
# install.
for ac_dir in $1; do
if test -f $ac_dir/install-sh; then
ac_aux_dir=$ac_dir
abs_ac_aux_dir=`(cd $ac_aux_dir && pwd)`
ac_install_sh="$abs_ac_aux_dir/install-sh -c"
break
elif test -f $ac_dir/install.sh; then
ac_aux_dir=$ac_dir
abs_ac_aux_dir=`(cd $ac_aux_dir && pwd)`
ac_install_sh="$abs_ac_aux_dir/install.sh -c"
break
fi
done
fi
if test -z "$ac_aux_dir"; then
AC_MSG_ERROR([can not find install-sh or install.sh in $1])
fi